Menambahkan Case Menu/Change Case di Microsoft Excel 2010

          Jika di Microsoft Word 2010 maupun versi sebelumnya Case menu atau sering disebut Change Case sudah tersedia, namun di Microsoft Excel 2010 maupun versi sebelumnya, Case Menu atau Change Case tidak tersedia.   Fungsi dari Case menu atau Change Case  adalah untuk merubah kata atau kalimat dengan beberapa pilihan antara lain Sentense case, lowercase, UPPERCASE, Capitalize Each word dan tOOGLE cASE.   Change Case ini jika di Microsoft Word berada pada tab HOME.

          Awal dari ide untuk menambahkan Case Menu/ Change Case pada Microsoft Excel 2010 sebenarnya karena telinga saya yang bising dengan keluhan rekan-rekan kerja yang tergabung dalam team pembuat PJK . ........ Apa itu PJK ???? Ndak usah diributkan ndak penting.... anggap saja Pembuat Jari Keriting...  Dalam pembuatan PJK, team ini menggunakan Microsoft  EXCEL 2010.  Nah, saat mengumpulkan data personel dari masing-masing sumber "terpercaya" ( menurut saya) ternyata data yang dibutuhkan  menggunakan huruf KAPITAL semua..... padahal aturannya,   penggunaan huruf kapital hanya di awal kalimat atau nama orang saja.

       Dari berselancar dengan mata yang pedas karena cahaya LCD, akhirnya saya menemukan tip EXCEL yang mantap.... walaupun saya ndak mudeng dengan bahasanya..... maklum aku hanya lulusan fakultas KERIS SAMUDERA Gunung Sari SBY.....namun sudah saya praktekkan dan saya kembangkan dengan cara saya sendiri .... alhamdulillah 1000 % berhasil, jadi saya memberanikan diri untuk  share di blog ini, .... sehingga pengunjung blog ini mampu membuat sesuatu yang berguna bagi orang lain dan tidak hanya menjadi user saja. 

Aplikasi yang dibutuhkan adalah :

1.   Microsoft Office 2010

2.   Custom UI Editor , untuk aplikasi ini silahkan donwload di link yang ada dibawah ini.... gratis dan tidak ada survey dari Share Chase yang bikin hati ndongkol.......

http://openxmldeveloper.org/archive/2006/05/26/CustomUIeditor.aspx

Proses pembuatan Change Case ini hanya butuh waktu kurang dari 5 menit.

Langsung pada pembahasan, pada tutorial ini saya menggunakan Windows 7 Ultimate 64 bit.

1.  Install Custom UI Editor

2.  Buka Microsoft Excel 2010, tidak usah mengetik apapun.  Save AS dalam format Excel Macro - Enabled Workbook lalu tutup Microsoft Excel 2010.  Secara default file tersebut akan berjudul seperti ini : Book1.xlsm , namun dalam tutorial ini file tersebut saya beri nama Case Menu 2010.xlsm.

3.  Buka Custom UI Editor, kemudian klik open file - buka file yang telah dibuat - klik kanan pada file - pilih  Office 2010 Custom UI Part, sehingga muncul "custom UI14.xml.

4. Arahkan mouse pada custom UI14.xml, copy script dibawah ini pada ruang kosong di sebelah kanan.

<customUI xmlns="http://schemas.microsoft.com/office/2009/07/customui">
   <contextMenus>
      <contextMenu idMso="ContextMenuCell">

         <button id="DuplicateBuiltInButton1" label="Save"
insertBeforeMso="Cut"
onAction="BuiltInSaveCommand"
imageMso="FileSave"/>

         <button id="MyButton" label="Toggle Case Upper/Lower/Proper"
         insertBeforeMso="Cut"
        onAction="ToggleCaseMacro"
        imageMso="HappyFace"/>

         <menu id="MySubMenu" label="Case Menu" insertBeforeMso="Cut"  >
            <button id="Menu1Button1" label="Upper Case"
            imageMso="U" onAction="UpperMacro"/>
            <button id="Menu1Button2" label="Lower Case"
            imageMso="L" onAction="LowerMacro"/>
            <button id="Menu1Button3" label="Proper Case"
            imageMso="P" onAction="ProperMacro"/>
         </menu>

        <menuSeparator id="MySeparator" insertBeforeMso="Cut" />

      </contextMenu>
   </contextMenus>
</customUI>

Kemudian simpan dan tutup Custom UI editor anda.... lihat gambar dibawah ini.

 5.    Sekarang buka file tersebut dengan menggunakan Microsoft Excel 2010 dengan cara klik kanan pada file - open with.....pilih Microsoft Excel.

6.    Setelah Microsoft Excel 2010 terbuka,  kita harus menampilkan tab DEVELOPER dengan cara  klik FILE - OPTIONS - pilih Customize Ribbon - centang DEVELOPER.  Aktifkan tab Developer lalu klik VISUAL BASIC.

7.       Klik kanan pada VBAProject (Case Menu 2010.xlsm) - Insert - Module.

8.     Arahkan mouse pada Module1, lalu copy dan paste script dibawah ini :

Sub ToggleCaseMacro(control As IRibbonControl)
    Dim CaseRange As Range
    Dim CalcMode As Long
    Dim cell As Range

    On Error Resume Next
    Set CaseRange = Intersect(Selection, _
        Selection.Cells.SpecialCells(xlCellTypeConstants, xlTextValues))
    If CaseRange Is Nothing Then Exit Sub

    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    For Each cell In CaseRange
        Select Case cell.Value
        Case UCase(cell.Value): cell.Value = LCase(cell.Value)
        Case LCase(cell.Value): cell.Value = StrConv(cell.Value, vbProperCase)
        Case Else: cell.Value = UCase(cell.Value)
        End Select
    Next cell

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

Sub UpperMacro(control As IRibbonControl)
    Dim CaseRange As Range
    Dim CalcMode As Long
    Dim cell As Range

    On Error Resume Next
    Set CaseRange = Intersect(Selection, _
        Selection.Cells.SpecialCells(xlCellTypeConstants, xlTextValues))
    If CaseRange Is Nothing Then Exit Sub

    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    For Each cell In CaseRange
        cell.Value = UCase(cell.Value)
    Next cell

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

Sub LowerMacro(control As IRibbonControl)
    Dim CaseRange As Range
    Dim CalcMode As Long
    Dim cell As Range

    On Error Resume Next
    Set CaseRange = Intersect(Selection, _
        Selection.Cells.SpecialCells(xlCellTypeConstants, xlTextValues))
    If CaseRange Is Nothing Then Exit Sub

    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    For Each cell In CaseRange
        cell.Value = LCase(cell.Value)
    Next cell

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

Sub ProperMacro(control As IRibbonControl)
    Dim CaseRange As Range
    Dim CalcMode As Long
    Dim cell As Range

    On Error Resume Next
    Set CaseRange = Intersect(Selection, _
        Selection.Cells.SpecialCells(xlCellTypeConstants, xlTextValues))
    If CaseRange Is Nothing Then Exit Sub

    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    For Each cell In CaseRange
        cell.Value = StrConv(cell.Value, vbProperCase)
    Next cell

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

Lihat gambar dibawah ini :

9.    Save.  Pada proses save ini saya sarankan simpan dalam format  Excel Add-In pada Users -nama komputer anda - AppData - Roaming - Microsoft - AddIns. (biasanya automatis).   Jika untuk komputer lain silahkan di copi pada flashdisk file tersebut.

10.   Silahkan test... ketikkan kalimat dengan huruf kecil  pada sembarang cell, kemudian klik kanan pada cell yang sudah ada tulisannya, jika penerapan script anda benar maka akan terlihat seperti gambar dibawah ini.

Cara menerapkan Add-in Case Menu 2010 pada komputer lain :

1.   Buka Microsoft Excel 2010
2.   Klik FILE - Option  - Add-Ins - klik GO pada Manage,  lihat gambar dibawah.

3.   Pada jendela Add-Ins, klik pada browser sehingga muncul jendela browser.  Silahkan cari file Case Menu 2010 lalu tekan OK, sehingga muncul jendela konfirmasi.  Silahkan klik Yes, sehingga Case Menu 2010 akan ditambahkan pada jendela Add-Ins dengan kotak kecil tercentang.  Lihat gambar dibawah ini.

4.   Silahkan cek hasilnya dengan klik pada cell yang mau dirubah. 

Berikut ini adalah perbandingan gambar :

*   Workbook sebelum kita terapkan Case Menu 2010

*   Workbook sesudah kita terapkan Case Menu 2010.

Mudah bukan, silahkan dicoba dan semoga bermanfaat. Saya yakin pasti bisa, mengingat proses pembuatannya sudah saya jelaskan step by step.  Namun tidak menutup kemungkinan jika anda tidak mau susah payah atau mendadak memerlukan CASE MENU MICROSOFT EXCEL 2010 ini , silahkan tinggalkan email anda pada kotak komentar.  Insya Allah akan saya kirim.......

Oh ya, jika  anda kurang puas silahkan belajar di http://www.rondebruin.nl/contextmenu.htm